Meep Tutorial/Optical forces

From AbInitio

(Difference between revisions)
Jump to: navigation, search
Revision as of 12:29, 1 October 2012 (edit)
Ardavan (Talk | contribs)

← Previous diff
Revision as of 12:30, 1 October 2012 (edit)
Ardavan (Talk | contribs)

Next diff →
Line 89: Line 89:
(display-forces wvg-force) (display-forces wvg-force)
-(If MPB 1.5 is not installed, simply remove all the lines pertaining to <code>changes-sources!</code> and the simulation will still work.)+(If MPB 1.5 is not installed, simply remove all lines pertaining to <code>changes-sources!</code> and the simulation will still work, though with reduced accuracy.)
Note that we have defined a single flux surface (spanning an area slightly larger than both waveguides) rather than two separate flux planes, one for each waveguide. This is because in the limit of small separation, two flux planes will overlap thus slightly complicating the analysis whereas the total power through a single flux plane need, by symmetry, only be halved in order to determine the value for just one of the two waveguides. Also note that instead of defining a closed, four-sided "box" surrounding the waveguide for computing the MST, we chose instead to compute the MST along <i>two</i> <code>y</code>-oriented lines (with different <code>weight</code>s to correctly sum the total force), one on each side of the waveguide since by symmetry we need not consider the force in the <code>y</code> direction. Finally, we must mention that the MST computed by Meep does <b>not</b> include a factor of 1/2, which is necessary if correctly defining the force in cgs units and therefore should be added in post processing. Note that we have defined a single flux surface (spanning an area slightly larger than both waveguides) rather than two separate flux planes, one for each waveguide. This is because in the limit of small separation, two flux planes will overlap thus slightly complicating the analysis whereas the total power through a single flux plane need, by symmetry, only be halved in order to determine the value for just one of the two waveguides. Also note that instead of defining a closed, four-sided "box" surrounding the waveguide for computing the MST, we chose instead to compute the MST along <i>two</i> <code>y</code>-oriented lines (with different <code>weight</code>s to correctly sum the total force), one on each side of the waveguide since by symmetry we need not consider the force in the <code>y</code> direction. Finally, we must mention that the MST computed by Meep does <b>not</b> include a factor of 1/2, which is necessary if correctly defining the force in cgs units and therefore should be added in post processing.

Revision as of 12:30, 1 October 2012

Here we will demonstrate Meep's ability to compute classical forces using the Maxwell stress tensor (MST) as well as the eigenmode source feature which integrates the frequency-domain functionality of our other open-source tool MPB (note that this will require Meep 1.2 and MPB 1.5, or greater). Our example consists of two identical dielectric waveguides (made of non-lossy Silicon with a square cross section) supporting identical modes while separated in space. Due to the symmetry and orientation of the waveguide profile, the two modes can be chosen to be either symmetric or anti-symmetric with respect to a mirror plane between them. As the two waveguides are brought closer and closer together, the individual guided modes couple more and more and give rise to an optical gradient force that is transverse to the waveguide axis (this is to be contrasted with radiation pressure that involves momentum exchange between photons and is longitudinal in nature). An interesting phenomena that occurs for this particular system is that the sign of the force can be tuned to be either attractive or repulsive depending on just the relative phase of the two modes which we will demonstrate in this tutorial.

The optical gradient force arising from the evanescent coupling of the modes of two adjacent structures can, in addition to the MST, be computed using the following analytic expression:

F=-\frac{1}{\omega}\frac{d\omega}{ds}\Bigg\vert_\vec{k}U,

where ω is the eigenmode frequency of the coupled-waveguide system, s is the separation distance between the parallel waveguides, k is the conserved wave vector and U is the total energy of the electromagnetic fields (for more details, see the original paper by Povinelli et al.). By convention, negative and positive values correspond to attractive and repulsive forces, respectively. This expression has been shown to be mathematically equivalent to the Maxwell stress tensor method and in this tutorial we will verify this result by Rakich et al. for the parallel-waveguide example. It is convenient to normalize the force so as to eliminate the tricky units altogether and since we know that the total power transmitted through the waveguide is P = vgU / L (vg is the group velocity, L is the waveguide length and U is defined as before), we focus instead on the force per unit length and power (F / L)(ac / P) (a is an arbitrary unit length and c is the speed of light). This dimensionless quantity enables us to compute both the flux and the force in a single simulation, without the need for a preliminary run where the scattering/displaced objects are absent (as described in a previous tutorial).

We can therefore compute the optical gradient force in two ways, one indirect and the other direct: 1) using any frequency-domain solver (in our case MPB), we compute the eigenmode frequency (and corresponding group velocity) for a mode with a fixed propagating wavevector at a number of different separation distances and then use a finite-difference scheme to evaluate the above expression and 2) in Meep, we compute both the force using the MST and the power transmitted through the waveguide only at the frequency corresponding to the guided mode. In this particular example, we consider just the fundamental y-odd mode, which happens to clearly show the bi-directional features of the force.

First, let us set up the two-dimensional computational cell (although since we are interested in a propagating mode of the structure which requires an axial wavevector, this technically will be a three-dimensional simulation)

 (set-param! resolution 30)
 (define-param nSi 3.45)
 (define Si (make medium (index nSi)))
 (define-param dpml 1.0)
 (define-param sx 5)
 (define-param sy 3)
 (set! geometry-lattice 
     (make lattice (size (+ sx (* 2 dpml)) (+ sy (* 2 dpml)) no-size)))
 (set! pml-layers (list (make pml (thickness dpml))))
 (define-param sw 1.0) ; waveguide width
 (define-param s 1.0)  ; waveguide separation distance
 (set! geometry (list 
       (make block (center (* -0.5 (+ s sw)) 0)
             (size sw sw infinity) (material Si))
       (make block (center (*  0.5 (+ s sw)) 0)
             (size sw sw infinity) (material Si))))

There are two mirror symmetries that we can exploit to reduce the simulation size by a factor of four.

 (define-param xodd? true)
 (set! symmetries (list 
        (make mirror-sym (direction X) (phase (if xodd? -1 +1)))
        (make mirror-sym (direction Y) (phase -1))))

Next, we set the Bloch-periodic boundary condition in order to excite a specific guided mode of the waveguide system (corresponding to a wavevector of π / a)

 (define-param beta 0.5)
 (set! k-point (vector3 0 0 beta))

Since we do not know apriori what the eigenmode frequency will be at any given separation distance, we first excite a spectrum of frequencies using a broadband point-dipole source positioned in the middle of each waveguide and then determine the resonant frequency using harminv. The use of a Bloch periodic boundary condition in the z direction will mean that the excited mode (if any) will propagate indefinitely in time which is why we stop the simulation at a fixed runtime after the Gaussian sources have turned off (choosing a suitable runtime requires some care since larger values closer to a steady-state response will in turn lead to larger Fourier-transformed fields, used to compute both the Poynting vector and the MST, which might cause instabilities in floating-point arithmetic).

 (define-param fcen 0.22)
 (define-param df 0.06)
 (set! sources (list 
         (make source (src (make gaussian-src (frequency fcen) (fwidth df))) 
                (component Ey) (center (* -0.5 (+ s sw)) 0))
         (make source (src (make gaussian-src (frequency fcen) (fwidth df))) 
                (component Ey) (center (* 0.5 (+ s sw)) 0) (amplitude (if xodd? -1.0 1.0)))))
 (define-param runtime 200)
 (run-sources+ runtime 
     (after-sources (harminv Ey (vector3 (* 0.5 (+ s sw)) 0) fcen df)))
 (define f (harminv-freq-re (car harminv-results)))
 (print "freq:, " s ", " f "\n")

Once we have determined what the eigenmode frequency is, we then use this value to accurately excite the mode of interest using the eigenmode-source feature and also compute the force on the waveguide and the power in the guided mode only at this value. The eigenmode-mode feature invokes MPB via a library routine in order to compute the relevant mode of interest and subsequently imports the (steady-state) field profile into the Meep simulation for use as the initial amplitude of the source. This then enables an efficient excitation of the relevant eigenmode of interest in the time domain to a much higher degree of accuracy than would otherwise be possible had we simply used a point-dipole source (the details of this will be described in chapter 4, soon to be made freely-available online, of our upcoming book).

 (reset-meep)
 (change-sources! (list
    (make eigenmode-source
      (src (make gaussian-src (frequency f) (fwidth df)))
      (component Ey)
      (size sw sw 0)
      (center (* -0.5 (+ s sw)) 0)
      (eig-kpoint k-point)
      (eig-match-freq? true)
      (eig-parity ODD-Y))
    (make eigenmode-source
      (src (make gaussian-src (frequency f) (fwidth df)))
      (component Ey)
      (size sw sw 0)
      (center (* 0.5 (+ s sw)) 0)
      (eig-kpoint k-point)
      (eig-match-freq? true)
      (eig-parity ODD-Y)
      (amplitude (if xodd? -1.0 1.0)))))
 (define wvg-pwr (add-flux f 0 1
    (make flux-region (direction Z) (center 0 0) 
 	   (size (* 1.2 (+ (* 2 sw) s)) (* 1.2 sw) 0))))
 (define-param dpad 0.1)
 (define wvg-force (add-force f 0 1
   (make force-region (direction X) (weight +1.0) 
         (center (- (* 0.5 s) dpad) 0) (size 0 sy))
   (make force-region (direction X) (weight -1.0) 
         (center (+ (* 0.5 s) sw dpad) 0) (size 0 sy))))
 (run-sources+ runtime)
 (display-fluxes wvg-pwr)
 (display-forces wvg-force)

(If MPB 1.5 is not installed, simply remove all lines pertaining to changes-sources! and the simulation will still work, though with reduced accuracy.)

Note that we have defined a single flux surface (spanning an area slightly larger than both waveguides) rather than two separate flux planes, one for each waveguide. This is because in the limit of small separation, two flux planes will overlap thus slightly complicating the analysis whereas the total power through a single flux plane need, by symmetry, only be halved in order to determine the value for just one of the two waveguides. Also note that instead of defining a closed, four-sided "box" surrounding the waveguide for computing the MST, we chose instead to compute the MST along two y-oriented lines (with different weights to correctly sum the total force), one on each side of the waveguide since by symmetry we need not consider the force in the y direction. Finally, we must mention that the MST computed by Meep does not include a factor of 1/2, which is necessary if correctly defining the force in cgs units and therefore should be added in post processing.

We run this simulation over a range of separation distances and compare the result to that obtained from MPB which shows good agreement.

Normalized force per unit length and input power versus waveguide separation of two parallel waveguides.
Personal tools